inzi.com

@echo off
cls
::
:: Set Parameters used by script
::

:: MySQl DB user
set MYSQLUSER=

:: MySQl DB users password
set MYSQLPASS=

:: Max days for archive
set MaxDays=7

::
:: Working Folders
::
:: Must Include Trailing Slash excpt for thebackupfolder
::

:: Where is the backup folder 
set backupFolder=c:\backup\

:: Path to folder where mysqldump.exe is 
set mySqlBinFolder=C:\Program Files\MySQL\MySQL Server 5.1\bin\

:: Path to where the MySQL data files are 
set mySqlDataFolder=C:\ProgramData\MySQL\MySQL Server 5.1\data\

:: Path to your wordpress site 
set PathToWordpress=C:\inetpub\wordpress\

:: Path to the folder where 7Zip is installed. This script uses 7z.exe 
set Pathto7zaexe=C:\Program Files\7-Zip\

:: End User Parameters
::
:: BEGIN VARIABLE SETUP
::

:: Convert to 8.3

set backupFolder83=
FOR /F "delims=" %%I in ('echo %backupFolder%') do set backupFolder83=%backupFolder83%%%~sI

set archiveFolder83=%backupFolder83%Archive

set mySqlBinFolder83=
FOR /F "delims=" %%I in ('echo %mySqlBinFolder%') do set mySqlBinFolder83=%mySqlBinFolder83%%%~sI

set mySqlDataFolder83=
FOR /F "delims=" %%I in ('echo %mySqlDataFolder%') do set mySqlDataFolder83=%mySqlDataFolder83%%%~sI

set PathToWordpress83=
FOR /F "delims=" %%I in ('echo %PathToWordpress%') do set PathToWordpress83=%PathToWordpress83%%%~sI

set Pathto7zaexe83=
FOR /F "delims=" %%I in ('echo %Pathto7zaexe%') do set Pathto7zaexe83=%Pathto7zaexe83%%%~sI



:: Executables

set MySqlDump=%mySqlBinFolder83%mysqldump.exe

set SevenZ=%Pathto7zaexe83%7z.exe

::
:: Working Variables
::

set DOW=%DATE:~0,3%
set MONTH=%DATE:~4,2%
set DAY=%DATE:~7,2%
set YEAR=%DATE:~10,4%

IF %TIME:~0,2% LSS 10 (
 SET HOUR=0%TIME:~1,1%
) ELSE (
 SET HOUR=%TIME:~0,2%
)

IF %TIME:~3,2% LSS 10 (
 SET MINUTE=0%TIME:~4,1%
) ELSE (
 SET MINUTE=%TIME:~3,2%
)

set ArchiveDate=%YEAR%-%MONTH%

set FileDate=%DOW%-%ArchiveDate%-%DAY%-%HOUR%-%MINUTE%

set DBBackupZip=%backupFolder83%FullDBbackup.%FileDate%.bk.zip

set WPBackupZip=%backupFolder83%FullWPbackup.%FileDate%.bk.zip

set CompleteBackupZip=%backupFolder83%Completebackup.%FileDate%.bk.zip

set ArchiveBackupZip=%backupFolder83%\archive\Archivebackup.%ArchiveDate%.bk.zip

@echo Verifying if %archiveFolder83% exists and if not create it

gogo:Label1
if NOT EXIST %archiveFolder83%\nul (
	@echo archive folder not found, creating %archiveFolder83%
	mkdir %archiveFolder83%
	@echo created...
)

:Label1
::
:: Begin Backup
::

@echo Starting ...

@echo . 

:: Switch to MYSQL Data folder
pushd %mySqlDataFolder83%
@echo Pass each folder name in %mySqlDataFolder83% to mysqldump.exe and output an individual .sql file for each database
FOR /D %%F IN (*) DO (
%MySqlDump% --user=%MYSQLUSER% --password=%MYSQLPASS% --databases --log-error="%backupFolder83%MySQLDumpError.txt" %%F > "%backupFolder83%%%F.%backupdate%.sql"
)
@echo .
@echo Delete the file %DBBackupZip% if it exists
if exist %DBBackupZip% (del %DBBackupZip%)

@echo .
@echo Zip all files ending in .sql in the folder %backupFolder83% to the file %DBBackupZip%
%SevenZ% a -tzip %DBBackupZip% %backupFolder83%*.sql

@echo .
@echo Delete all the files ending in .sql only
del %backupFolder83%*.sql

@echo .
@echo Deleting zip files older than %MaxDays% days
forfiles /p %backupFolder83:~0,-1% /M *.zip /D -%MaxDays% /C "cmd /c del @Path /Q" 2>&1 | find /v /i "ERROR: No files found"
::goto:endofline

@echo .
@echo Create a new archive of the wordpress folder
%SevenZ% a -tzip "%WPBackupZip%" "%PathToWordpress83%"


@echo .
@echo Ensure there is no complete backup for this day in the folder:
if EXIST %CompleteBackupZip% (
	del %CompleteBackupZip%
)


@echo .
@echo merge DB and WP archives into single archive with zero compression 
%SevenZ% a -tzip -mx0 "%CompleteBackupZip%" "%WPBackupZip%" "%DBBackupZip%"


@echo .
@echo create a monthly archive
::set MonthlyArchive=%backupFolder83%monthlybackup.%year%.%mnt%.zip
if %day% EQU 09 (
@echo First of the month, creating archive
	copy %CompleteBackupZip% %ArchiveBackupZip%
)


@echo .
@echo Removing temp archives
forfiles /p %backupFolder83:~0,-1% /M Full*.bk.zip /C "cmd /c del @Path /Q" 2>&1 | find /v /i "ERROR: No files found"

@echo .
@echo returning to starting folder

:endofline
popd